[Release] Epoch Admin Tools V1.10.0

[Chainsaw Squirrel]

Link me to the ai you are using. I just did tests with wai. I tried blowing myself up, crashing, falling 700m, getting shot with mounted ai weapons, and more with no problem. I feel it may be something with how that system handles player damage.

Also can be killed by players as well it seems.. not just AI .. and another thing I found.. seems that over 15 players , spectate doesn't show list of all players .. and only shows some of the players on the map at one time

AS I had 35 on and could only view some .. as the list only seems to go like 2 pages

[NoxSicarius]

Also can be killed by players as well it seems.. not just AI .. and another thing I found.. seems that over 15 players , spectate doesn't show list of all players .. and only shows some of the players on the map at one time

AS I had 35 on and could only view some .. as the list only seems to go like 2 pages

 

I know that some group managers cause an issue with these. You may want to try installing the tools again, keep the config, but replace the other files. The problem doesn't seem to be the tools. The only time I die with god mode is if I go in and out of a safe zone.

[SmokeyBR]

Also can be killed by players as well it seems.. not just AI .. and another thing I found.. seems that over 15 players , spectate doesn't show list of all players .. and only shows some of the players on the map at one time

AS I had 35 on and could only view some .. as the list only seems to go like 2 pages

 

ur saying godmod is not working at all ? if youre using infistar safezones then theres the cause for it.

 

also.. as NoxSicarius stated above group manager will mess your player ESP when players are in it, not showing player or showing the wrong player name....

[Chainsaw Squirrel]

 

ur saying godmod is not working at all ? if youre using infistar safezones then theres the cause for it.

 

also.. as NoxSicarius stated above group manager will mess your player ESP when players are in it, not showing player or showing the wrong player name....

 

Yea using infistar safe zone.. just no longer using infistar... any work around ?? and I hate AGN safe zone !

[C.Peck]

Yea using infistar safe zone.. just no longer using infistar... any work around ?? and I hate AGN safe zone !

Search for gmadmin in the safe zone script and replace every instance of it with playerGod2

[Chainsaw Squirrel]

Search for gmadmin in the safe zone script and replace every instance of it with playerGod2

Thank U -

 

can I remark out the Epoch Antihack with bypass, seems since I put that in some players having hard time logging in stuck hear sounds cant log all the way in .. maybe 2 out of 10 .. with infistar didn't have the issue

[NoxSicarius]

Thank U -

 

can I remark out the Epoch Antihack with bypass, seems since I put that in some players having hard time logging in stuck hear sounds cant log all the way in .. maybe 2 out of 10 .. with infistar didn't have the issue

 

This has been known to happen at times even on clean servers. Doesn't have anything to do with the antihack changes. All I did was make admins exempt from the location test and players exempt from the location test only when they are put in a special list. This list is loaded before they get into the game so it can't be holding them at a black screen.

[Chainsaw Squirrel]

This has been known to happen at times even on clean servers. Doesn't have anything to do with the antihack changes. All I did was make admins exempt from the location test and players exempt from the location test only when they are put in a special list. This list is loaded before they get into the game so it can't be holding them at a black screen.

Ok Thanx Nox .. just trying to resolve

[Chainsaw Squirrel]

Search for gmadmin in the safe zone script and replace every instance of it with playerGod2

 

Peck that did nothing LOL

[C.Peck]

Peck that did nothing LOL

Post the safezone script you're using and which verison of the tools are you using? Worked for me.

 

also check out this post for the issue with people not being able to log in fully, haven't had a single report since I made the suggested changes.

 

[NoxSicarius]

I will start updating this again soon. I have been dealing with some medical problems that have taken up a good deal of my time.

[Willids]

Hi Guys

Been away a while due to health issues and just got my server back running, does this run on the latest A2 Cherno latest version?

 

Thanks

[NoxSicarius]

Hi Guys

Been away a while due to health issues and just got my server back running, does this run on the latest A2 Cherno latest version?

 

Thanks

 

yes. 1.0.5.1

[Willids]

yes. 1.0.5.1

Thanks for this reply, does it work on Overpoch ?

[Wootywoop]

Thanks for this reply, does it work on Overpoch ?

 

Hey Willids - Yes it does. I'm running Overpoch with the test branch of these tools and can confirm it all works. :)  

[Willids]

Thanks for that need some scripts for it, Self blood etc so downloading them now.

 

I am using vilayers, anyone else using them and know where the mission files are, I have downloaded 2 lots of folders/files at the moment.

 

- dayz_overpoch file which has compile, init, missions (no overpoch folder in there), modules & system folders.

 

- missions folder which has overpoch.chernarus (with folder ca and files description.ext, init.sqf, mission.sqm and server_traders.sqf)

 

All help would be grateful.

 

Thanks

[NoxSicarius]

I need some help guys. If you have this installed AND have Snap Pro from Raymix, please test this out for me.

This script update should add in snap capabilities to the instant admin build system. Will not work with the buildings, but should work with standard epoch items.

 

Go into admintools -> tools -> AdminBuild

Open adminBuild.sqf and paste in the following code:

/*
	Modified version of Raymix's snap pro player build to work with admin build
*/
private ["_helperColor","_objectHelper","_objectHelperDir","_objectHelperPos","_canDo","_location","_dir","_classname","_item","_cancel","_reason","_tmpbuilt","_text","_offset",
"_IsNearPlot","_isOk","_location1","_location2","_position","_object","_findNearestPoles","_findNearestPole","_distance","_classnametmp","_ghost","_isPole","_needText","_lockable",
"_zheightchanged","_rotate","_combination_1","_combination_2","_combination_3","_combination_4","_combination","_combination_1_Display","_combinationDisplay","_zheightdirection",
"_vehicle","_inVehicle","_objHDiff","_isLandFireDZ"];

if(DZE_ActionInProgress) exitWith { cutText [(localize "str_epoch_player_40") , "PLAIN DOWN"]; };

//snap vars -- temporary fix for errors so variables.sqf can be skipped
if (isNil "snapProVariables") then {
	if (isNil "DZE_snapExtraRange") then {
		DZE_snapExtraRange = 0;
	};
	if (isNil "DZE_checkNearbyRadius") then {
		DZE_checkNearbyRadius = 30;
	};
	s_player_toggleSnap = -1;
	s_player_toggleSnapSelect = -1;
	s_player_toggleSnapSelectPoint=[];
	snapActions = -1;
	snapGizmos = [];
	snapGizmosNearby = [];
	snapProVariables = true; // will skip this statement from now on.
};
// snap vars

_cancel = false;
_reason = "";
_vehicle = vehicle player;
_inVehicle = (_vehicle != player);
_canDo = call fnc_actionAllowed;

helperDetach = false; 

DZE_Q = false;
DZE_Z = false;

DZE_Q_alt = false;
DZE_Z_alt = false;

DZE_Q_ctrl = false;
DZE_Z_ctrl = false;

DZE_5 = false;
DZE_4 = false;
DZE_6 = false;
DZE_F = false;

DZE_cancelBuilding = false;

call gear_ui_init;
closeDialog 1;

if(isNil 'isBuilding') then {isBuilding = false};
if(!_canDo) exitWith {cutText ["Cannot build while on ladder, in water, in vehicle","PLAIN DOWN"];};

if((_this select 0) == "rebuild") then {
	if(isNil "adminRebuildItem") exitWith {systemChat "You have not selected a buildable item yet"};
	_item =	adminRebuildItem;
	_isPerm = adminRebuildPerm;
} else {
	_item =	_this select 0;
	adminRebuildItem = _item;
	isBuilding = _this select 1;
	_isPerm = _this select 2;
	adminRebuildPerm = _isPerm;
};

// Need Near Requirements
_reason = "";

_classname = getText (configFile >> "CfgMagazines" >> _item >> "ItemActions" >> "Build" >> "create");
_classnametmp = _classname;
_text = getText (configFile >> "CfgVehicles" >> _classname >> "displayName");
_ghost = getText (configFile >> "CfgVehicles" >> _classname >> "ghostpreview");

_lockable = 0;
if(isNumber (configFile >> "CfgVehicles" >> _classname >> "lockable")) then {
	_lockable = getNumber(configFile >> "CfgVehicles" >> _classname >> "lockable");
};

_isAllowedUnderGround = 1;
if(isNumber (configFile >> "CfgVehicles" >> _classname >> "nounderground")) then {
	_isAllowedUnderGround = getNumber(configFile >> "CfgVehicles" >> _classname >> "nounderground");
};

_offset = 	getArray (configFile >> "CfgVehicles" >> _classname >> "offset");
if((count _offset) <= 0) then {
	if(isBuilding) then {
		if(_item in (buildResidential - buildShed)) then {
			_offset = [0,15,2];
		} else {
			if(_item in (buildCastle + buildMilitary)) then {
				_offset = [0,3,2];
			} else {
				if(_item in buildReligious) then {
					_offset = [0,25,2];
				} else {
					if(_item in buildGrave + buildOutdoors) then {
						_offset = [0,2,1];
					} else {
						_offset = [0,6,2];
					};
				};
			};
		};
	} else {
		_offset = [0,2,0];
	};
};

_isPole = (_classname == "Plastic_Pole_EP1_DZ");
_isLandFireDZ = (_classname == "Land_Fire_DZ");

_distance = DZE_PlotPole select 0;
_needText = localize "str_epoch_player_246";

if(_isPole) then {
	_distance = DZE_PlotPole select 1;
};

// check for near plot
_findNearestPoles = nearestObjects [(vehicle player), ["Plastic_Pole_EP1_DZ"], _distance];
_findNearestPole = [];

{
	if (alive _x) then {
		_findNearestPole set [(count _findNearestPole),_x];
	};
} count _findNearestPoles;

_IsNearPlot = count (_findNearestPole);

// If item is plot pole && another one exists within 45m
if(_isPole && _IsNearPlot > 0) exitWith {  DZE_ActionInProgress = false; cutText [(localize "str_epoch_player_44") , "PLAIN DOWN"]; };

_location = [0,0,0];
_isOk = true;

// get inital players position
_location1 = [player] call FNC_GetPos;
_dir = getDir player;

// if ghost preview available use that instead
if (_ghost != "") then {
	_classname = _ghost;
};

_object = createVehicle [_classname, _location, [], 0, "CAN_COLLIDE"];
//Build Gizmo
_objectHelper = "Sign_sphere10cm_EP1" createVehicle _location;
_helperColor = "#(argb,8,8,3)color(0,0,0,0,ca)";
_objectHelper setobjecttexture [0,_helperColor];
_objectHelper attachTo [player,_offset];
_object attachTo [_objectHelper,[0,0,0]];
_position = [_objectHelper] call FNC_GetPos;
	
_objHDiff = 0;

if (isClass (missionConfigFile >> "SnapBuilding" >> _classname)) then {	
	["","","",["Init",_object,_classname,_objectHelper]] spawn snap_build;
};
	
while {_isOk} do {

	_zheightchanged = false;
	_zheightdirection = "";
	_rotate = false;

	if (DZE_Q) then {
		DZE_Q = false;
		_zheightdirection = "up";
		_zheightchanged = true;
	};
	if (DZE_Z) then {
		DZE_Z = false;
		_zheightdirection = "down";
		_zheightchanged = true;
	};
	if (DZE_Q_alt) then {
		DZE_Q_alt = false;
		_zheightdirection = "up_alt";
		_zheightchanged = true;
	};
	if (DZE_Z_alt) then {
		DZE_Z_alt = false;
		_zheightdirection = "down_alt";
		_zheightchanged = true;
	};
	if (DZE_Q_ctrl) then {
		DZE_Q_ctrl = false;
		_zheightdirection = "up_ctrl";
		_zheightchanged = true;
	};
	if (DZE_Z_ctrl) then {
		DZE_Z_ctrl = false;
		_zheightdirection = "down_ctrl";
		_zheightchanged = true;
	};
	if (DZE_4) then {
		_rotate = true;
		DZE_4 = false;
		_dir = -45;
	};
	if (DZE_6) then {
		_rotate = true;
		DZE_6 = false;
		_dir = 45;
	};
	if (DZE_F and _canDo) then {	
		if (helperDetach) then {
			_objectHelperDir = getDir _objectHelper; 
			_objectHelper attachTo [player];
			_objectHelper setDir _objectHelperDir-(getDir player);
			helperDetach = false;
		} else {
			_objectHelperDir = getDir _objectHelper;
			detach _objectHelper;
			[_objectHelper]	call FNC_GetSetPos;
			_objectHelper setVelocity [0,0,0]; //fix sliding glitch
			helperDetach = true;
		};
		DZE_F = false;
	};

	if(_rotate) then {
		if (helperDetach) then {
			_objectHelperDir = getDir _objectHelper;
			_objectHelper setDir _objectHelperDir+_dir;
			[_objectHelper]	call FNC_GetSetPos;
		} else {
			detach _objectHelper;
			_objectHelperDir = getDir _objectHelper;
			_objectHelper setDir _objectHelperDir+_dir;
			[_objectHelper]	call FNC_GetSetPos;
			_objectHelperDir = getDir _objectHelper;
			_objectHelper attachTo [player];
			_objectHelper setDir _objectHelperDir-(getDir player);		
		};
	};

	if(_zheightchanged) then {
		if (!helperDetach) then {
			detach _objectHelper;
			_objectHelperDir = getDir _objectHelper;
		};

		_position = [_objectHelper] call FNC_GetPos;
		
		if(_zheightdirection == "up") then {
			_position set [2,((_position select 2)+0.1)];
			_objHDiff = _objHDiff + 0.1;
		};
		if(_zheightdirection == "down") then {
			_position set [2,((_position select 2)-0.1)];
			_objHDiff = _objHDiff - 0.1;
		};

		if(_zheightdirection == "up_alt") then {
			_position set [2,((_position select 2)+1)];
			_objHDiff = _objHDiff + 1;
		};
		if(_zheightdirection == "down_alt") then {
			_position set [2,((_position select 2)-1)];
			_objHDiff = _objHDiff - 1;
		};

		if(_zheightdirection == "up_ctrl") then {
			_position set [2,((_position select 2)+0.01)];
			_objHDiff = _objHDiff + 0.01;
		};
		if(_zheightdirection == "down_ctrl") then {
			_position set [2,((_position select 2)-0.01)];
			_objHDiff = _objHDiff - 0.01;
		};

		if((_isAllowedUnderGround == 0) && ((_position select 2) < 0)) then {
			_position set [2,0];
		};

		if (surfaceIsWater _position) then {
			_objectHelper setPosASL _position;
		} else {
			_objectHelper setPosATL _position;
		};

		if (!helperDetach) then {
			_objectHelper attachTo [player];
			_objectHelper setDir _objectHelperDir-(getDir player);
		};
	};

	sleep 0.5;

	_location2 = [player] call FNC_GetPos;
	_objectHelperPos = [_objectHelper] call FNC_GetPos;

	if(DZE_5) exitWith {
		_isOk = false;
		_position = [_object] call FNC_GetPos;
		detach _object;
		_dir = getDir _object;
		deleteVehicle _object;
		detach _objectHelper;
		deleteVehicle _objectHelper;
	};

	if(_location1 distance _location2 > 10) exitWith {
		_isOk = false;
		_cancel = true;
		_reason = "You've moved to far away from where you started building (within 10 meters)";
		detach _object;
		deleteVehicle _object;
		detach _objectHelper;
		deleteVehicle _objectHelper;
	};
		
	if(_location1 distance _objectHelperPos > 10) exitWith {
		_isOk = false;
		_cancel = true;
		_reason = "Object is placed to far away from where you started building (within 10 meters)";
		detach _object;
		deleteVehicle _object;
		detach _objectHelper;
		deleteVehicle _objectHelper;
	};

	if(abs(_objHDiff) > 10) exitWith {
		_isOk = false;
		_cancel = true;
		_reason = "Cannot move up or down more than 10 meters";
		detach _object;
		deleteVehicle _object;
		detach _objectHelper;
		deleteVehicle _objectHelper;
	};

	if (player getVariable["combattimeout", 0] >= time) exitWith {
		_isOk = false;
		_cancel = true;
		_reason = (localize "str_epoch_player_43");
		detach _object;
		deleteVehicle _object;
		detach _objectHelper;
		deleteVehicle _objectHelper;
	};

	if (DZE_cancelBuilding) exitWith {
		_isOk = false;
		_cancel = true;
		_reason = "Cancelled building.";
		detach _object;
		deleteVehicle _object;
		detach _objectHelper;
		deleteVehicle _objectHelper;
	};
};


if(!_cancel) then {
	_classname = _classnametmp;

	// Start Build
	_tmpbuilt = createVehicle [_classname, _location, [], 0, "CAN_COLLIDE"];

	_tmpbuilt setdir _dir;

	// Get position based on object
	_location = _position;

	if((_isAllowedUnderGround == 0) && ((_location select 2) < 0)) then {
		_location set [2,0];
	};

	if (surfaceIsWater _location) then {
		_tmpbuilt setPosASL _location;
		_location = ASLtoATL _location;
	} else {
		_tmpbuilt setPosATL _location;
	};

	cutText [format[(localize "str_epoch_player_138"),_text], "PLAIN DOWN"];

	cutText [format[localize "str_build_01",_text], "PLAIN DOWN"];
			
	if (_isPole) then {
		[] spawn player_plotPreview;
	};

	_tmpbuilt setVariable ["OEMPos",_location,true];

	if(_lockable > 1) then {
		_combinationDisplay = "";

		switch (_lockable) do {
			case 2: { // 2 lockbox
				_combination_1 = (floor(random 3)) + 100; // 100=red,101=green,102=blue
				_combination_2 = floor(random 10);
				_combination_3 = floor(random 10);
				_combination = format["%1%2%3",_combination_1,_combination_2,_combination_3];
				dayz_combination = _combination;
				if (_combination_1 == 100) then {
					_combination_1_Display = "Red";
				};
				if (_combination_1 == 101) then {
					_combination_1_Display = "Green";
				};
				if (_combination_1 == 102) then {
					_combination_1_Display = "Blue";
				};
				_combinationDisplay = format["%1%2%3",_combination_1_Display,_combination_2,_combination_3];
			};

			case 3: { // 3 combolock
				_combination_1 = floor(random 10);
				_combination_2 = floor(random 10);
				_combination_3 = floor(random 10);
				_combination = format["%1%2%3",_combination_1,_combination_2,_combination_3];
				dayz_combination = _combination;
				_combinationDisplay = _combination;
			};

			case 4: { // 4 safe
				_combination_1 = floor(random 10);
				_combination_2 = floor(random 10);
				_combination_3 = floor(random 10);
				_combination_4 = floor(random 10);
				_combination = format["%1%2%3%4",_combination_1,_combination_2,_combination_3,_combination_4];
				dayz_combination = _combination;
				_combinationDisplay = _combination;
			};
		};

		_tmpbuilt setVariable ["CharacterID",_combination,true];

		PVDZE_obj_Publish = [_combination,_tmpbuilt,[_dir,_location],_classname];
		publicVariableServer "PVDZE_obj_Publish";
		cutText [format[(localize "str_epoch_player_140"),_combinationDisplay,_text], "PLAIN DOWN", 5];
	} else {
		if(_isPerm) then {
			_tmpbuilt setVariable ["CharacterID",dayz_characterID,true];
		
			// fire?
			if(_tmpbuilt isKindOf "Land_Fire_DZ") then {
				_tmpbuilt spawn player_fireMonitor;
			} else {
				PVDZE_obj_Publish = [dayz_characterID,_tmpbuilt,[_dir,_location],_classname];
				publicVariableServer "PVDZE_obj_Publish";
			};
		};
	};
	
	// Tool use logger
	if(logMinorTool) then {
		usageLogger = format["%1 %2 -- has used admin build to place: %3",name player,getPlayerUID player,_item];
		[] spawn {publicVariable "usageLogger";};
	};
} else {
	deleteVehicle _tmpbuilt;
	r_interrupt = false;
	cutText [(localize "str_epoch_player_46") , "PLAIN DOWN"];
};
 

[NoxSicarius]

Thanks for that need some scripts for it, Self blood etc so downloading them now.

 

I am using vilayers, anyone else using them and know where the mission files are, I have downloaded 2 lots of folders/files at the moment.

 

- dayz_overpoch file which has compile, init, missions (no overpoch folder in there), modules & system folders.

 

- missions folder which has overpoch.chernarus (with folder ca and files description.ext, init.sqf, mission.sqm and server_traders.sqf)

 

All help would be grateful.

 

Thanks

 

Make edits to one, see if it works.

[Willids]

I have added the admin tools and actions to the server and put them in a folder so all my addons are in one folder.

 

Other then changing this - actions\FunMenu\morph.sq to something like addons\actions\FunMenu\morph.sq should I need to change anything else as the admin as Teleport is working but a few other thing are not/

 

I am running Overpoch

 

Thanks

[NoxSicarius]

I have added the admin tools and actions to the server and put them in a folder so all my addons are in one folder.

 

Other then changing this - actions\FunMenu\morph.sq to something like addons\actions\FunMenu\morph.sq should I need to change anything else as the admin as Teleport is working but a few other thing are not/

 

I am running Overpoch

 

Thanks

 

You will need to go through all the files and modify their pathing where necessary. It is advised to always follow the install guide to mods unless you know what you are getting into. When dealing with an expansive mod like this, it is not worth the time to modify the pathing.

[hellraver]

The Weather Time menu works beautifully. Only after each server restart is day and not the regular daytime. But I could fix the problem in the AdminList.sqf :-) Self is the man ;-)

[NoxSicarius]

The Weather Time menu works beautifully. Only after each server restart is day and not the regular daytime. But I could fix the problem in the AdminList.sqf :-) Self is the man ;-)

 

Has anyone complained about the time change not working properly? I have heard isolated accounts of this, but nothing concrete shown to me.

[NoxSicarius]

I am gearing up for a large version release soon. I just finished another round of optimization on the scripts and I could really use some info on if that snap-build pro fix I asked about is working. I have a way to auto-detect if snap build is installed so if the adminbuild replacement file works it will natively support snap pro without user modification. 

[Wootywoop]

I am gearing up for a large version release soon. I just finished another round of optimization on the scripts and I could really use some info on if that snap-build pro fix I asked about is working. I have a way to auto-detect if snap build is installed so if the adminbuild replacement file works it will natively support snap pro without user modification. 

 

Hi Nox,

 

In the post about the admin snap fix you say to paste the code into the adminBuild.sqf - is there any specific place that it should be? Will placing it at the bottom of the existing file suffice?

 

Or should it replace the entire file? ** Having looked at the text i'd guess the entire file needs replacing.**

[hellraver]

Has anyone complained about the time change not working properly? I have heard isolated accounts of this, but nothing concrete shown to me.

Yes I complained but at the same time resolved the issue. What I do not understand that this problem no one noticed. But a counter-question, has anyone complained about the vehicle key changer not working properly? No one noticed it. Not even the developer. But it was a Bug exists that allowed vehicles infinitely duplicate. 100% reproducible. But nobody complained as in this case.

The Weather Time menu works beautifully. The times are all taken from the server. The only problem is after each server restart is day and not the regular daytime. Is it for example 10 pm and night and I reboot the server, is suddenly daylight. It is always daylight at server restart. Due to a bug in the AdminList.sqf, the server reboots always with daylight and never with the regular daytime. But the change of weather and the time working wonderful. Here there are no problems.

But I could fix the problem in the AdminList.sqf. I fix all problems that I find :-) The Weapon Kits.sqf also has a bug.

Sorry for my bad english. I come from Austria ;-)

best regards

hellraver