Jump to content

[Outdated] [Community-Project] Fully Updated DayZ OverPochIns Taviana Server

nidico100

By nidico100
in A2: Epoch Mods

 Share

Recommended Posts

nidico100 Newbie

nidico100

Posted
Posted

Hey guys,

I just came back from a long break. I saw that most DayZ Mod Communities are nearly dead. I wanted to host a Overpochins Server again, but couldn't find any nearly updated Serverfiles, so I decided to make a project out of this.

Due to university and job I don't have 24/7 time for working on this, so maybe someone wants to participate to make this project get updated faster. Else it could take a while for me alone. The Files will always be public and everyone has access to them on my Gitlab.

My goal is to have fully updated Server Files with the probably last versions of the DayZ Mod's. And to have them public for everyone, so the small community, which is left can use those files to directly start a server and have fun.

In my eyes the best base to start with are ElDubya's Files, which you can find here: Link

I've already uploaded his files in the Git and added some Milestones. I will start some work in a few days. If anyone want to help just reply here and I can add you as Member to the Git.

Link to the Gitlab: Link

Link to comment
Share on other sites
  • 2 weeks later...
nidico100 Newbie

nidico100

Posted
  • Author
Posted
17 minutes ago, Mig said:

Hello,

Ssome time ago I started working on a project epoch 1.0.6.2 and origins 1.8.3,

I will resume the project that I will have time.

There is no time pressure so just relax. You can pull-request your changes to the gitlab, if you want to, then other people can help you with optimizations and fixes

Link to comment
Share on other sites
Mig Newbie

Mig

Posted
Posted
42 minutes ago, nidico100 said:

i thought it would be easier to start with old files and update them instead of starting from the scratch

no, there is too much to update it is simpler to start from scratch with the epoch server file.

44 minutes ago, nidico100 said:

you are using epoch as base-mod, right?

Yes 

Link to comment
Share on other sites
l1nkrx7 Newbie

l1nkrx7

Posted
Posted

here is what i have for building houses

 

fn_selfActions.sqf

Quote 

if(DZE_Origins_Building_System) then {
    if(isnil "s_player_build_origins_house") then {s_player_build_origins_house = -1;};
    if(isnil "s_player_build_origins_garage") then {s_player_build_origins_garage = -1;};
    if(isnil "s_player_build_origins_stronghold") then {s_player_build_origins_stronghold = -1;};
    if(isnil "s_player_origins_unlock") then {s_player_origins_unlock = -1;};
    if(isnil "s_player_origins_stronghold_doors") then {s_player_origins_stronghold_doors = -1;};
    _cursorTarget = cursorTarget;
    if (!isNull _cursorTarget) then {
        _typeOfCursorTarget = (typeOf _cursorTarget);
        if(_typeOfCursorTarget == DZE_Origins_Container ) then {
            if((player distance _cursorTarget) < DZE_Origins_Build_Distance) then {
                private["_humanity","_playerUID","_hasLevel1","_hasLevel2","_hasLevel3","_hasSG","_hasLG","_hasKING","_hasSH","_canBuildHouse","_houselevel","_humanityNeed","_actionText","_classname","_neededMaterials","_canBuildSH","_canBuildGarage"];
                _humanity = player getVariable["humanity",0];
                _playerUID = dayz_playerUID;
                _hasLevel1 = (_playerUID in owner_H1 || _playerUID in owner_B1);
                _hasLevel2 = (_playerUID in owner_H2 || _playerUID in owner_B2);
                _hasLevel3 = (_playerUID in owner_H3 || _playerUID in owner_B3);
                _hasSG = (_playerUID in owner_SG);
                _hasLG = (_playerUID in owner_LG);
                _hasKING = (_playerUID in owner_KING);
                _hasSH = (_playerUID in owner_SH);

                {
                    _houselevel = _x select 0;
                    _humanityNeed = _x select 1;
                    _actionText = _x select 2;
                    _classname = _x select 3;
                    _neededMaterials = _x select 4;
                    _canBuildHouse = false;
                    _canBuildGarage = false;
                    _canBuildSH = false;

                    if((_humanityNeed > 0 && _humanity >= _humanityNeed) || (_humanityNeed < 0 && _humanity <= _humanityNeed)) then {
                        if(_houselevel in ["H1","B1"] && !_hasLevel1) then {
                            _canBuildHouse = true;
                        };
                        if(_houselevel in ["H2","B2"] && !_hasLevel2) then {
                            _canBuildHouse = true;
                        };
                        if(_houselevel in ["H3","B3"] && !_hasLevel3) then {
                            _canBuildHouse = true;
                        };
                        if(_houselevel in ["SGH","SGB"] && _hasLevel1 && !_hasSG) then {
                            _canBuildGarage = true;
                        };
                        if(_houselevel in ["LGH","LGB"] && _hasLevel3 && !_hasLG) then {
                            _canBuildGarage = true;
                        };
                        if(_houselevel in ["KINGH","KINGB"] && _hasLevel3 && _hasLG && !_hasKING) then {
                            _canBuildGarage = true;
                        };
                        if(_houselevel in ["SHH","SHB"] && _hasLevel1 && _hasLevel2 && _hasLevel3 && !_hasSH) then {
                            _canBuildSH = true;
                        };
                    };

                    if(_canBuildHouse) then {
                        if(s_player_build_origins_house < 0) then {
                            s_player_build_origins_house = player addAction ["Build " + _actionText, "origins\player_build.sqf", [_cursorTarget, _houselevel, _classname, _neededMaterials, _actionText]];
                        };
                    };
                    if(_canBuildGarage) then {
                        if(s_player_build_origins_garage < 0) then {
                            s_player_build_origins_garage = player addAction ["Build " + _actionText, "origins\player_build.sqf", [_cursorTarget, _houselevel, _classname, _neededMaterials, _actionText]];
                        };
                    };
                    if(_canBuildSH) then {
                        if(s_player_build_origins_stronghold < 0) then {
                            s_player_build_origins_stronghold = player addAction ["Build " + _actionText, "origins\player_build.sqf", [_cursorTarget, _houselevel, _classname, _neededMaterials, _actionText]];
                        };
                    };

                } forEach DZE_Origins_Build_HousesGarages;
            } else {
                [1] call origins_removeActions;
            };
        };

        if(_typeOfCursorTarget in DZE_Origins_Buildings && (player distance _cursorTarget) < DZE_Origins_LockUnlock_Distance) then {
            private["_ownerUID","_ownerName","_playerUID","_state","_openClose"];
            _playerUID = dayz_playerUID;
            _ownerUID = _cursorTarget getVariable ["OwnerUID","0"];
            _ownerName = _cursorTarget getVariable ["OwnerName","0"];
            _ownerID = 0;
            _friendlies = [];
            _canOPEN = false;
            _plotcheck = [player, false] call FNC_find_plots;
            _distance = DZE_PlotPole select 0;

            _IsNearPlot = _plotcheck select 1;
            _nearestPole = _plotcheck select 2;

            if (_IsNearPlot == 0) then {
                _canOPEN = false;
            } else {
                _ownerID = _nearestPole getVariable["CharacterID","0"];
                if (dayz_characterID == _ownerID) then {
                    _canOPEN = true;
                } else {
                    if (DZE_permanentPlot) then {
                        _buildcheck = [player, _nearestPole] call FNC_check_access;
                        _isowner = _buildcheck select 0;
                        _isfriendly = ((_buildcheck select 1) or (_buildcheck select 3));
                        if (_isowner || _isfriendly) then {
                            _canOPEN = true;
                        } else {
                            _canOPEN = false;
                        };
                    } else {
                        _friendlies    = player getVariable ["friendlyTo",[]];
                        if (_ownerID in _friendlies) then {
                            _canOPEN = true;
                        } else {
                            _canOPEN = false;
                        };
                    };
                };
            };
            if (!(_canOPEN)&& !(_typeOfCursorTarget in DZE_Origins_Stronghold)) exitWith {
                //cutText [format["You dont have permission to access this building!"], "PLAIN DOWN",5];
                cutText [format["This house was built by %1", _ownerName], "PLAIN DOWN",5];
            };




            _state = (_cursorTarget getVariable ["CanBeUpdated",false]);
            if(_typeOfCursorTarget in DZE_Origins_Stronghold && _state) then {
                private["_strongholdDoorsOpen"];
                _strongholdDoorsOpen = (_cursorTarget getVariable ["DoorsOpen",false]);
                if(_strongholdDoorsOpen) then {
                    if(s_player_origins_stronghold_doors < 0) then {
                        s_player_origins_stronghold_doors = player addAction [ "Close Doors","origins\origins_strongholdDoors.sqf",[_cursorTarget,0]];
                    };
                } else {
                    if(s_player_origins_stronghold_doors < 0)then {
                        s_player_origins_stronghold_doors = player addAction [ "Open Doors","origins\origins_strongholdDoors.sqf",[_cursorTarget,1]];
                    };
                };
            } else {
                [3] call origins_removeActions;
            };

            if(s_player_origins_unlock < 0) then {
                _matched = false;
                {
                    if(_typeOfCursorTarget == (_x select 0)) then {
                        if(_state) then {
                            _openClose = format["Lock %1", _X select 1];
                        } else {
                            _openClose = format["Unlock %1", _X select 1];
                        };
                        _matched = true;
                    };
                    if (_matched) exitWith {
                        s_player_origins_unlock = player addAction [_openClose, "origins\player_lockUnlock.sqf", [_cursorTarget,_typeOfCursorTarget,_state]];
                    };
                } count DZE_Origins_NameLookup;
            };
        } else {
            [2] call origins_removeActions;
        };
    } else {
        [0] call origins_removeActions;
    };
};

 

player_build.sqf

Quote 

/*
    DayZ Base Building
    Made for DayZ Epoch please ask permission to use/edit/distrubute email [email protected].
*/
private ["_location","_dir","_classname","_item","_hasrequireditem","_missing","_hastoolweapon","_cancel","_reason","_started","_finished","_animState","_isMedic","_dis","_sfx","_hasbuilditem","_tmpbuilt","_onLadder","_isWater","_require","_offset","_IsNearPlot","_isOk","_location1","_location2","_counter","_limit","_proceed","_num_removed","_position","_object","_canBuildOnPlot","_friendlies","_nearestPole","_ownerID","_findNearestPoles","_findNearestPole","_distance","_classnametmp","_ghost","_isPole","_needText","_lockable","_zheightchanged","_rotate","_combination_1","_combination_2","_combination_3","_combination_4","_combination","_combination_1_Display","_combinationDisplay","_zheightdirection","_abort","_isNear","_need","_needNear","_vehicle","_inVehicle","_requireplot","_objHDiff","_isLandFireDZ","_isTankTrap","_charID","_name","_objectID","_objectUID","_playerUID","_playerName","_combination","_playerID"];
 
if(DZE_ActionInProgress) exitWith { cutText [(localize "str_epoch_player_40") , "PLAIN DOWN"]; };
DZE_ActionInProgress = true;
 
// disallow building if too many objects are found within 30m
if((count ((getPosATL player) nearObjects ["All",30])) >= DZE_BuildingLimit) exitWith {DZE_ActionInProgress = false; cutText [(localize "str_epoch_player_41"), "PLAIN DOWN"];};
 
_onLadder =     (getNumber (configFile >> "CfgMovesMaleSdr" >> "States" >> (animationState player) >> "onLadder")) == 1;
_isWater =      dayz_isSwimming;
_cancel = false;
_reason = "";
_canBuildOnPlot = false;
 
_vehicle = vehicle player;
_inVehicle = (_vehicle != player);
 
DZE_Q = false;
DZE_Z = false;
 
DZE_Q_alt = false;
DZE_Z_alt = false;
 
DZE_Q_ctrl = false;
DZE_Z_ctrl = false;
 
DZE_5 = false;
DZE_4 = false;
DZE_6 = false;
 
DZE_cancelBuilding = false;
 
call gear_ui_init;
closeDialog 1;
 
if (_isWater) exitWith {DZE_ActionInProgress = false; cutText [localize "str_player_26", "PLAIN DOWN"];};
if (_inVehicle) exitWith {DZE_ActionInProgress = false; cutText [(localize "str_epoch_player_42"), "PLAIN DOWN"];};
if (_onLadder) exitWith {DZE_ActionInProgress = false; cutText [localize "str_player_21", "PLAIN DOWN"];};
if (player getVariable["combattimeout", 0] >= time) exitWith {DZE_ActionInProgress = false; cutText [(localize "str_epoch_player_43"), "PLAIN DOWN"];};
 
_crate = (_this select 3 select 0);
_houselevel = (_this select 3 select 1);
_classname = (_this select 3 select 2);
_neededMaterials = (_this select 3 select 3);
_name = (_this select 3 select 4);
_charID = dayz_characterID;
_playerUID = dayz_playerUID;
_playerName = (name player);
[1] call origins_removeActions;
 
_proceed = [_crate,_neededMaterials] call origins_checkNeededMaterial;
if(!_proceed) exitWith{DZE_ActionInProgress = false;};
 
// Need Near Requirements
_abort = false;
_reason = "";
 
_classnametmp = _classname;
 
_requireplot = DZE_requireplot;
_isAllowedUnderGround = 0;
if(_classname in DZE_Origins_Stronghold) then {
    _offset = [0,30,0];
} else {
    _offset = [0,10,0];
};
_isPole = (_classname == "Plastic_Pole_EP1_DZ");
_isLandFireDZ = (_classname == "Land_Fire_DZ");
 
_distance = DZE_PlotPole select 0;
_needText = localize "str_epoch_player_246";
 
if(_isPole) then {
    _distance = DZE_PlotPole select 1;
};
 
// check for near plot
_findNearestPoles = nearestObjects [(vehicle player), ["Plastic_Pole_EP1_DZ"], _distance];
_findNearestPole = [];
 
{
    if (alive _x) then {
        _findNearestPole set [(count _findNearestPole),_x];
    };
} count _findNearestPoles;
 
_IsNearPlot = count (_findNearestPole);
 
// If item is plot pole && another one exists within 45m
if(_isPole && _IsNearPlot > 0) exitWith {  DZE_ActionInProgress = false; cutText [(localize "str_epoch_player_44") , "PLAIN DOWN"]; };
 
if(_IsNearPlot == 0) then {
    // Allow building of plot
    if(_requireplot == 0 || _isLandFireDZ) then {
        _canBuildOnPlot = true;
    };
} else {
    // check nearby plots ownership && then for friend status
    _nearestPole = _findNearestPole select 0;
 
    // Find owner  
    _hasAccess  = false;
    _hasAccess  = [player, _nearestPole] call FNC_check_access;
    _allowed    = ((_hasAccess select 0) or (_hasAccess select 2) or (_hasAccess select 3) or (_hasAccess select 4));
    // 0= owner + 2= plot owner + 3= plot friends + 4=plot admins  
    if(_allowed) then {  //Keep ownership
        // owner can build anything within his plot except other plots
        _canBuildOnPlot = true; // 0= owner + 2= plot owner + 3= plot friends + 4=plot admins -> can build
    };
    // check if friendly to owner
    if(_playerID == _ownerID) then {  //Keep ownership
        // owner can build anything within his plot except other plots
        if(!_isPole) then {
            _canBuildOnPlot = true;
        };
    } else {
        // disallow building plot
        if(!_isPole) then {
            _friendlies     = player getVariable ["friendlyTo",[]];
            // check if friendly to owner
            if(_ownerID in _friendlies) then {
                _canBuildOnPlot = true;
            };
        };
    };
};
 
// _message
if(!_canBuildOnPlot) exitWith {  DZE_ActionInProgress = false; cutText [format[(localize "STR_EPOCH_PLAYER_135"),_needText,_distance] , "PLAIN DOWN"]; };
 
_require = DZE_Origins_Build_Tools_Require;
_missing = "";
_hasrequireditem = true;
{
    _hastoolweapon = _x in weapons player;
    if(!_hastoolweapon) exitWith { _hasrequireditem = false; _missing = getText (configFile >> "cfgWeapons" >> _x >> "displayName"); };
} count _require;
 
if (!_hasrequireditem) exitWith {DZE_ActionInProgress = false; cutText [format[(localize "str_epoch_player_137"),_missing] , "PLAIN DOWN"]; };
if (_hasrequireditem) then {
    _location = [0,0,0];
    _isOk = true;
 
    // get inital players position
    _location1 = getPosATL player;
    _dir = getDir player;
 
    _object = createVehicle [_classname, _location, [], 0, "CAN_COLLIDE"];
    _object attachTo [player,_offset];
    _position = getPosATL _object;
    cutText [(localize "str_epoch_player_45"), "PLAIN DOWN"];
    _objHDiff = 0;
 
    while {_isOk} do {
 
        _zheightchanged = false;
        _zheightdirection = "";
        _rotate = false;
 
        if (DZE_Q) then {
            DZE_Q = false;
            _zheightdirection = "up";
            _zheightchanged = true;
        };
        if (DZE_Z) then {
            DZE_Z = false;
            _zheightdirection = "down";
            _zheightchanged = true;
        };
        if (DZE_Q_alt) then {
            DZE_Q_alt = false;
            _zheightdirection = "up_alt";
            _zheightchanged = true;
        };
        if (DZE_Z_alt) then {
            DZE_Z_alt = false;
            _zheightdirection = "down_alt";
            _zheightchanged = true;
        };
        if (DZE_Q_ctrl) then {
            DZE_Q_ctrl = false;
            _zheightdirection = "up_ctrl";
            _zheightchanged = true;
        };
        if (DZE_Z_ctrl) then {
            DZE_Z_ctrl = false;
            _zheightdirection = "down_ctrl";
            _zheightchanged = true;
        };
        if (DZE_4) then {
            _rotate = true;
            DZE_4 = false;
            _dir = 180;
        };
        if (DZE_6) then {
            _rotate = true;
            DZE_6 = false;
            _dir = 0;
        };
 
        if(_rotate) then {
            _object setDir _dir;
            _object setPosATL _position;
            //diag_log format["DEBUG Rotate BUILDING POS: %1", _position];
        };
 
        if(_zheightchanged) then {
            detach _object;
 
            _position = getPosATL _object;
 
            if(_zheightdirection == "up") then {
                _position set [2,((_position select 2)+0.1)];
                _objHDiff = _objHDiff + 0.1;
            };
            if(_zheightdirection == "down") then {
                _position set [2,((_position select 2)-0.1)];
                _objHDiff = _objHDiff - 0.1;
            };
 
            if(_zheightdirection == "up_alt") then {
                _position set [2,((_position select 2)+1)];
                _objHDiff = _objHDiff + 1;
            };
            if(_zheightdirection == "down_alt") then {
                _position set [2,((_position select 2)-1)];
                _objHDiff = _objHDiff - 1;
            };
 
            if(_zheightdirection == "up_ctrl") then {
                _position set [2,((_position select 2)+0.01)];
                _objHDiff = _objHDiff + 0.01;
            };
            if(_zheightdirection == "down_ctrl") then {
                _position set [2,((_position select 2)-0.01)];
                _objHDiff = _objHDiff - 0.01;
            };
 
            _object setDir (getDir _object);
 
            if((_isAllowedUnderGround == 0) && ((_position select 2) < 0)) then {
                _position set [2,0];
            };
 
            _object setPosATL _position;
 
            //diag_log format["DEBUG Change BUILDING POS: %1", _position];
 
            _object attachTo [player];
 
        };
 
        sleep 0.5;
 
        _location2 = getPosATL player;
 
        if(DZE_5) exitWith {
            _isOk = false;
            detach _object;
            _dir = getDir _object;
            _position = getPosATL _object;
            //diag_log format["DEBUG BUILDING POS: %1", _position];
            deleteVehicle _object;
        };
 
        if(_location1 distance _location2 > 5) exitWith {
            _isOk = false;
            _cancel = true;
            _reason = "You've moved to far away from where you started building (within 5 meters)";
            detach _object;
            deleteVehicle _object;
        };
 
        if(abs(_objHDiff) > 5) exitWith {
            _isOk = false;
            _cancel = true;
            _reason = "Cannot move up || down more than 5 meters";
            detach _object;
            deleteVehicle _object;
        };
 
        if (player getVariable["combattimeout", 0] >= time) exitWith {
            _isOk = false;
            _cancel = true;
            _reason = (localize "str_epoch_player_43");
            detach _object;
            deleteVehicle _object;
        };
 
        if (DZE_cancelBuilding) exitWith {
            _isOk = false;
            _cancel = true;
            _reason = "Cancelled building.";
            detach _object;
            deleteVehicle _object;
        };
    };
 
    //No building on roads unless toggled
    if (!DZE_BuildOnRoads) then {
        if (isOnRoad _position) then { _cancel = true; _reason = "Cannot build on a road."; };
    };
 
    // No building in trader zones
    if(!canbuild) then { _cancel = true; _reason = "Cannot build in a city."; };
 
    if(!_cancel) then {
 
        _classname = _classnametmp;
 
        // Start Build
        _tmpbuilt = createVehicle [_classname, _location, [], 0, "CAN_COLLIDE"];
 
        _tmpbuilt setdir _dir;
 
        // Get position based on object
        _location = _position;
 
        if((_isAllowedUnderGround == 0) && ((_location select 2) < 0)) then {
            _location set [2,0];
        };
 
        _tmpbuilt setPosATL _location;
        if((_location select 2) < 0.25) then {
            _tmpbuilt setVectorUp surfaceNormal position _tmpbuilt;
        };
        _location = getPosATL _tmpbuilt;
 
        cutText [format[(localize "str_epoch_player_138"),_name], "PLAIN DOWN"];
 
        _limit = 3;
 
        if (DZE_StaticConstructionCount > 0) then {
            _limit = DZE_StaticConstructionCount;
        }
        else {
            if (isNumber (configFile >> "CfgVehicles" >> _classname >> "constructioncount")) then {
                _limit = getNumber(configFile >> "CfgVehicles" >> _classname >> "constructioncount");
            };
        };
 
        _isOk = true;
        _proceed = false;
        _counter = 0;
 
        while {_isOk} do {
 
            [10,10] call dayz_HungerThirst;
            player playActionNow "Medic";
 
            _dis=20;
            _sfx = "repair";
            [player,_sfx,0,false,_dis] call dayz_zombieSpeak;
            [player,_dis,true,(getPosATL player)] spawn player_alertZombies;
 
            r_interrupt = false;
            r_doLoop = true;
            _started = false;
            _finished = false;
 
            while {r_doLoop} do {
                _animState = animationState player;
                _isMedic = ["medic",_animState] call fnc_inString;
                if (_isMedic) then {
                    _started = true;
                };
                if (_started && !_isMedic) then {
                    r_doLoop = false;
                    _finished = true;
                };
                if (r_interrupt || (player getVariable["combattimeout", 0] >= time)) then {
                    r_doLoop = false;
                };
                if (DZE_cancelBuilding) exitWith {
                    r_doLoop = false;
                };
                sleep 0.1;
            };
            r_doLoop = false;
 
 
            if(!_finished) exitWith {
                _isOk = false;
                _proceed = false;
            };
 
            if(_finished) then {
                _counter = _counter + 1;
            };
 
            cutText [format[(localize "str_epoch_player_139"),_name, _counter,_limit], "PLAIN DOWN"];
 
            if(_counter == _limit) exitWith {
                _isOk = false;
                _proceed = true;
            };
 
        };
 
        if (_proceed) then {
            cutText [format[localize "str_build_01",_name], "PLAIN DOWN"];
 
            if (_isPole) then {
                [] spawn player_plotPreview;
            };
 
            if(_classname in DZE_Origins_Stronghold) then {
                private["_combination_1","_combination_2","_combination_3","_combination_4","_combination_5","_combination_6"];
                _combination = "";
                _combination_1 = ceil(random 9);
                while {_combination_1 == 0} do {
                    _combination_1 = ceil (random 9);
                };
                _combination_2 = ceil(random 9);
                _combination_3 = ceil(random 9);
                _combination_4 = ceil(random 9);
                _combination_5 = ceil(random 9);
                _combination_6 = ceil(random 9);
                _combination = format["%1%2%3%4%5%6",_combination_1,_combination_2,_combination_3,_combination_4,_combination_5,_combination_6];
                dayz_combination = _combination;
           
            };
            _tmpbuilt setVariable ["OEMPos",_location,true];
            _tmpbuilt setVariable ["CharacterID",dayz_characterID,true];
            _tmpbuilt setVariable ["OwnerUID",_playerUID, true];
            _tmpbuilt setVariable ["OwnerName",_playerName, true];
            _activatingPlayer = player;
               
            _proceed = [_crate,_neededMaterials] call origins_checkNeededMaterial;
            if(_proceed) then {
                switch (_houselevel) do {
                    case 'B1' : {
                        owner_B1 set [count owner_B1, _playerUID];
                        publicVariable "owner_B1";
                        player setVariable["DZE_Origins_Level1",true,true];
                    };
                    case 'B2' : {
                        owner_B2 set [count owner_B2, _playerUID];
                        publicVariable "owner_B2";
                        player setVariable["DZE_Origins_Level2",true,true];
                    };
                    case 'B3' : {
                        owner_B3 set [count owner_B3, _playerUID];
                        publicVariable "owner_B3";
                        player setVariable["DZE_Origins_Level3",true,true];
                    };
                    case 'H1' : {
                        owner_H1 set [count owner_H1, _playerUID];
                        publicVariable "owner_H1";
                        player setVariable["DZE_Origins_Level1",true,true];
                    };
                    case 'H2' : {
                        owner_H2 set [count owner_H2, _playerUID];
                        publicVariable "owner_H2";
                        player setVariable["DZE_Origins_Level2",true,true];
                    };
                    case 'H3' : {
                        owner_H3 set [count owner_H3, _playerUID];
                        publicVariable "owner_H3";
                        player setVariable["DZE_Origins_Level3",true,true];
                    };
                    case 'SGH';
                    case 'SGB' : {
                        owner_SG set [count owner_SG, _playerUID];
                        publicVariable "owner_SG";
                        player setVariable["DZE_Origins_SG",true,true];
                    };
                    case 'LGH';
                    case 'LGB' : {
                        owner_LG set [count owner_LG, _playerUID];
                        publicVariable "owner_LG";
                        player setVariable["DZE_Origins_LG",true,true];
                    };
                    case 'KINGH';
                    case 'KINGB' : {
                        owner_KING set [count owner_KING, _playerUID];
                        publicVariable "owner_KING";
                        player setVariable["DZE_Origins_KING",true,true];
                    };
                    case 'SHH';
                    case 'SHB' : {
                        owner_SH set [count owner_SH, _playerUID];
                        publicVariable "owner_SH";
                        player setVariable["DZE_Origins_SH",true,true];
                    };
                };
                if(_classname in DZE_Origins_Stronghold) then {
                    //PVDZ_obj_Publish = [dayz_playerUID,_tmpbuilt,[_dir,_location,dayz_playerUID],[]];
                    PVDZ_obj_Publish = [_combination,_tmpbuilt,[_dir,_location,dayz_playerUID],[],player,dayz_authKey];
                    //PVDZ_obj_Publish = [_combination,_tmpbuilt,[_dir,_location,dayz_playerUID],[]];
                    //PVDZ_obj_Publish = [_tmpbuilt,[_dir,_location,_playerUID],_classname,true,dayz_combination,_activatingPlayer];
                    publicVariableServer  "PVDZ_obj_Publish";
                    cutText [format[(localize "str_epoch_player_140"),_combination,_name], "PLAIN DOWN", 5];
                } else {
                    //PVDZ_obj_Publish = [dayz_playerUID,_tmpbuilt,[_dir,_location,dayz_playerUID],[]];
                    PVDZ_obj_Publish = [dayz_characterID,_tmpbuilt,[_dir,_location,dayz_playerUID],[],player,dayz_authKey];
                    publicVariableServer  "PVDZ_obj_Publish";
                    cutText [format["Nice one! You now have a %1", _name], "PLAIN DOWN",5];
                };
                clearWeaponCargoGlobal  _crate;
                clearMagazineCargoGlobal  _crate;
                clearBackpackCargoGlobal _crate;
               
                _objectID = _crate getVariable["ObjectID","0"];
                _objectUID = _crate getVariable["ObjectUID","0"];
                PVDZ_obj_Destroy = [_objectID,_objectUID,_activatingPlayer];
                publicVariableServer "PVDZ_obj_Destroy";
                if (isServer) then {
                    PVDZ_obj_Destroy call server_deleteObjDirect;
                };
                deleteVehicle _crate;
            } else {
                deleteVehicle _tmpbuilt;
            };
 
        } else {
            r_interrupt = false;
            if (vehicle player == player) then {
                [objNull, player, rSwitchMove,""] call RE;
                player playActionNow "stop";
            };
 
            deleteVehicle _tmpbuilt;
 
            cutText [(localize "str_epoch_player_46") , "PLAIN DOWN"];
        };
 
    } else {
        cutText [format[(localize "str_epoch_player_47"),_name,_reason], "PLAIN DOWN"];
    };
};
 
DZE_ActionInProgress = false;

 

 

Link to comment
Share on other sites
  • 2 weeks later...
  • 6 months later...
  • 1 month later...
  • 3 weeks later...
don2k7 Newbie

don2k7

Posted
Posted
On 6/13/2019 at 6:18 PM, Mig said:

yes

ok a couple of questions

1. is there anything i can help with?

2. would anyone be willing to share how they got building origin houses and elctronests to work using epoch 1.0.6.2 and origins 1.83?

3. has anyone got building the reinforced walls, upgrading armour on cars and wearing the origins body armour working?

edit*

using epoch 1.0.6.2 and origins 1.8.3 I've managed to get the origin houses and stronghold to build and stay after server restart. the problem i have is that when once built the crate and materials for making them disappear but nothing will unlock or lock (so cant check gear storage at this point). on the houses and garages i don't even get the option to unlock/lock but i get the unlock option for the stronghold but once you enter the code nothing happens. after restart the houses and stronghold are still there but the crate and building supplies used to make them are also there as well.

 

 

Link to comment
Share on other sites
  • 4 months later...
  • 2 years later...
Guest
This topic is now closed to further replies.
 Share
Go to topic listing
  • Advertisement

  • Discord

×
×
  • Create New...