Humanity System dayz epoch

[DEN17101996]

Where can i find Humanity config

i want to balance it and share with all

i have some ideas to make other system

so players would be have fun because an humanity edited system is very interesting thing.

i only need for it, help where i can edit all humanity +/- medical zombies bandit kills survior kills hero kills  damage

[3steN8igall]

dayz_code.pbo >> compile >> player_death.sqf

[DEN17101996]

dayz_code.pbo >> compile >> player_death.sqf

thanks i try to edit

 

private ["_display","_body","_playerID","_array","_source","_method","_canHitFree","_isBandit","_punishment","_humanityHit","_myKills","_humanity","_kills","_killsV","_myGroup"];

disableSerialization;

if (deathHandled) exitWith {};

deathHandled = true;

if ((alive player) && {isNil {dayz_playerName}}) then {

    dayz_playerName = name player;

};

//Prevent client freezes

_display = findDisplay 49;

if(!isNull _display) then {_display closeDisplay 0;};

if (dialog) then {closeDialog 0;};

if (visibleMap) then {openMap false;};

_body = player;

_playerID = getPlayerUID player;

disableUserInput true;

//add weapon on back to player...

//if (dayz_onBack != "") then {

//    _body addWeapon dayz_onBack;

//};

_infected = 0;

if (r_player_infected && DZE_PlayerZed) then {

    _infected = 1;

};

PVDZE_plr_Died = [dayz_characterID,0,_body,_playerID,_infected, dayz_playerName];

publicVariableServer "PVDZE_plr_Died";

_id = [player,20,true,getPosATL player] call player_alertZombies;

sleep 0.5;

player setDamage 1;

0.1 fadeSound 0;

player setVariable ["NORRN_unconscious", false, true];

player setVariable ["unconsciousTime", 0, true];

player setVariable ["USEC_isCardiac",false,true];

player setVariable ["medForceUpdate",true,true];

player setVariable ["startcombattimer", 0];

r_player_unconscious = false;

r_player_cardiac = false;

_array = _this;

if (count _array > 0) then {

    _source = _array select 0;

    _method = _array select 1;

    if ((!isNull _source) && (_source != player)) then {

        _canHitFree = player getVariable ["freeTarget",false];

        _isBandit = (player getVariable["humanity",0]) <= -2000;

        _punishment = _canHitFree || _isBandit; //if u are bandit || start first - player will not recieve humanity drop

        _humanityHit = 0;

        if (!_punishment) then {

            //i'm "not guilty" - kill me && be punished

            _myKills = ((player getVariable ["humanKills",0]) / 30) * 1000;

            _humanityHit = -(2000 - _myKills);

            _kills = _source getVariable ["humanKills",0];

            _source setVariable ["humanKills",(_kills + 1),true];

            PVDZE_send = [_source,"Humanity",[_source,_humanityHit,300]];

            publicVariableServer "PVDZE_send";

        } else {

            //i'm "guilty" - kill me as bandit

            _killsV = _source getVariable ["banditKills",0];

            _source setVariable ["banditKills",(_killsV + 1),true];

        };

    };

    _body setVariable ["deathType",_method,true];

};

terminate dayz_musicH;

terminate dayz_slowCheck;

terminate dayz_animalCheck;

terminate dayz_monitor1;

terminate dayz_medicalH;

terminate dayz_gui;

r_player_dead = true;

"dynamicBlur" ppEffectEnable true;"dynamicBlur" ppEffectAdjust [4]; "dynamicBlur" ppEffectCommit 0.2;

"colorCorrections" ppEffectEnable true;

"colorCorrections" ppEffectAdjust [1, 1, 0, [1, 1, 1, 0.0], [1, 1, 1, 0.01],  [1, 1, 1, 0.0]];

"colorCorrections" ppEffectCommit 1;

//Player is Dead!

3 fadeSound 0;

sleep 1;

dayz_originalPlayer enableSimulation true;

addSwitchableUnit dayz_originalPlayer;

setPlayable dayz_originalPlayer;

selectPlayer dayz_originalPlayer;

//_myGroup = group _body;

//[_body] joinSilent dayz_firstGroup;

//deleteGroup _myGroup;

3 cutRsc ["default", "PLAIN",3];

4 cutRsc ["default", "PLAIN",3];

_body setVariable["combattimeout", 0, true];

//["dayzFlies",player] call broadcastRpcCallAll;

sleep 2;

1 cutRsc ["DeathScreen","BLACK OUT",3];

playMusic "dayz_track_death_1";

"dynamicBlur" ppEffectAdjust [0]; "dynamicBlur" ppEffectCommit 5;

"colorCorrections" ppEffectAdjust [1, 1, 0, [1, 1, 1, 0.0], [1, 1, 1, 1],  [1, 1, 1, 1]];"colorCorrections" ppEffectCommit 5;

sleep 2;

for  "_x" from 5 to 1 step -1 do {

    titleText [format[localize "str_return_lobby", _x], "PLAIN DOWN", 1];

    sleep 1;

};

PVDZE_Server_Simulation = [_body, false];

publicVariableServer "PVDZE_Server_Simulation";

endMission "END1";

 

 

how i can remove humanity gain for kills anybody <_<

i want that for kills surviors hero or bandit humanity will dont change.

[BetterDeadThanZed]

dayz_code.pbo >> compile >> player_death.sqf

 

I don't see anything in there that defines how much humanity you get for each action (bloodbag, killing a zed, killing a player, etc.). Can you point out what I'm missing?

[HeroeZGaming]

Humanity gain from Zeds is located in local_eventKill.sqf

dayz_code\compile\local_eventKill.sqf

//[unit, selectionName, damage, source, projectile]
//will only run when local to the created object
//record any key hits to the required selection
private ["_zed","_killer","_kills","_array","_type","_humanity"];

_array =         _this select 0;
_zed =             _array select 0;
_killer =         _array select 1;
_type =         _this select 1;

if (local _zed) then {
    _kills = _killer getVariable[_type,0];
    _killer setVariable[_type,(_kills + 1),true];

    //increase players humanity when zed killed
    _humanity = _killer getVariable["humanity",0];
    _humanity = _humanity + 5;
    _killer setVariable["humanity",_humanity,true];
};

 

Humanity given for giving a bloodbag to another player is in transfusion.sqf

dayz_code\medical\transfusion.sqf

private ["_started","_finished","_animState","_isMedic","_num_removed","_unit","_lastused"];
// bleed.sqf
_unit = (_this select 3) select 0;
//_lowBlood =     _unit getVariable ["USEC_lowBlood", false];
//_injured =         _unit getVariable ["USEC_injured", false];
//_inPain =         _unit getVariable ["USEC_inPain", false];
//_lastused =     _unit getVariable ["LastTransfusion", time];

// if (_lastused - time < 60) exitwith {cutText [format[(localize "str_actions_medical_18"),_text] , "PLAIN DOWN"]};

call fnc_usec_medic_removeActions;
r_action = false;

// not possible to transfuse while in a vehicle
if (vehicle player != player) exitWith { };

player playActionNow "Medic";

[1,1] call dayz_HungerThirst;

r_interrupt = false;
_animState = animationState player;
r_doLoop = true;
_started = false;
_finished = false;
while {r_doLoop} do {
    _animState = animationState player;
    _isMedic = ["medic",_animState] call fnc_inString;
    if (_isMedic) then {
        _started = true;
    };
    if (_started && !_isMedic) then {
        r_doLoop = false;
        _finished = true;
    };
    if (r_interrupt) then {
        r_doLoop = false;
    };
    sleep 0.1;
};
r_doLoop = false;

if (_finished) then {
    //_unit setVariable["LastTransfusion",time,true]; //reserve for self transfusion
    _unit setVariable["USEC_lowBlood",false,true];
    _num_removed = ([player,"ItemBloodbag"] call BIS_fnc_invRemove);
    if(_num_removed == 1) then {
    
        /* PVS/PVC - Skaronator */
        PVDZE_send = [_unit,"Transfuse",[_unit,player]];
        publicVariableServer "PVDZE_send";

        [player,100] call player_humanityChange;
    };
} else {
    r_interrupt = false;
    player switchMove "";
    player playActionNow "stop";
};

[DEN17101996]

I have change all humanity +/-  and will test it on private server next week,

changed files >>>

dayz_code.pbo

 

transfusion.sqf

painkiller.sqf

morphine.sqf

bandage.sqf

variables.sqf

local_eventKill.sqf

player_death.sqf

fn_damageHandler.sqf

fn_damageActions.sqf

fn_selfActions

[3steN8igall]

I don't see anything in there that defines how much humanity you get for each action (bloodbag, killing a zed, killing a player, etc.). Can you point out what I'm missing?

 

its only for adding humanity for player kills, den17**** marks it blue in his post

the other humanity adds are in each files......look one post above

[DEN17101996]

its only for adding humanity for player kills, den17**** marks it blue in his post

the other humanity adds are in each files......look one post above

3steN8igall can you help me with weapon penalty

AS50 >=5000 humanity and when player is under 5000 Humanity he will no do damage with AS50