[HELP] New random vehicle spawns causing error

[MatthewK]

Edit: Our vehicle list only allows for 1 of each vehicle to spawn in the wild. I noticed that 2 of each for most of them , even though before the restart there were non. Strange!

I've only just noticed this today after deleting all the old unused empty vehicles off my server. When it restarted my logs got spammed with this:

Spoiler

>
19:32:30   Error Undefined variable in expression: _vehicle
19:32:30 File z\addons\dayz_server\init\server_functions.sqf, line 250
19:32:30 Error in expression <imit = _random select 1;
 
_qty = {_x == _vehicle} count serverVehicleCounter;
 
 
>
19:32:30   Error position: <_vehicle} count serverVehicleCounter;


>
19:32:31   Error Undefined variable in expression: _vehicle
19:32:31 File z\addons\dayz_server\init\server_functions.sqf, line 250
19:32:31 Error in expression <VehiclesList select _index;
 
_vehicle = _random select 0;
_velimit = _random sel>
19:32:31   Error position: <_random select 0;
_velimit = _random sel>
19:32:31   Error Undefined variable in expression: _random
19:32:31 File z\addons\dayz_server\init\server_functions.sqf, line 247
19:32:31 "PUBLISH: Attempt 2959d0c0# 769227: an2.p3d"
19:32:31 "HIVE: WRITE: "CHILD:308:7:AN2_DZ:0:0:[158,[8422.04,8500.55,0.809721]]:[]:[["glass1",0.714594],["glass2",0.596947],["glass3",0.567447],["glass4",0.426075],["telo",0.611188]]:0.258463:84220850058158:""
19:32:31 Error in expression <imit = _random select 1;
 
_qty = {_x == _vehicle} count serverVehicleCounter;
 
 
>
19:32:31   Error position: <_vehicle} count serverVehicleCounter;

 

 

This is my spawn function: which looks fine to me. The variables are all defined at least!

Spoiler

spawn_vehicles = {
	private ["_random","_lastIndex","_weights","_index","_vehicle","_velimit","_qty","_isAir","_isShip","_position","_dir","_istoomany","_veh","_objPosition","_marker","_iClass","_itemTypes","_cntWeights","_itemType","_num","_allCfgLoots"];
	
	if (!isDedicated) exitWith { }; //Be sure the run this

	while {count AllowedVehiclesList > 0} do {
		// BIS_fnc_selectRandom replaced because the index may be needed to remove the element
		_index = floor random count AllowedVehiclesList;
		_random = AllowedVehiclesList select _index;

		_vehicle = _random select 0;
		_velimit = _random select 1;

		_qty = {_x == _vehicle} count serverVehicleCounter;

		// If under limit allow to proceed
		if (_qty <= _velimit) exitWith {};

		// vehicle limit reached, remove vehicle from list
		// since elements cannot be removed from an array, overwrite it with the last element && cut the last element of (as long as order is not important)
		_lastIndex = (count AllowedVehiclesList) - 1;
		if (_lastIndex != _index) then {
			AllowedVehiclesList set [_index, AllowedVehiclesList select _lastIndex];
		};
		AllowedVehiclesList resize _lastIndex;
	};

	if (count AllowedVehiclesList == 0) then {
		diag_log("DEBUG: unable to find suitable vehicle to spawn");
	} else {

		// add vehicle to counter for next pass
		serverVehicleCounter set [count serverVehicleCounter,_vehicle];
	
		// Find Vehicle Type to better control spawns
		_isAir = _vehicle isKindOf "Air";
		_isShip = _vehicle isKindOf "Ship";
	
		if(_isShip || _isAir) then {
			if(_isShip) then {
				// Spawn anywhere on coast on water
				waitUntil{!isNil "BIS_fnc_findSafePos"};
				_position = [MarkerPosition,0,DynamicVehicleArea,10,1,2000,1] call BIS_fnc_findSafePos;
				//diag_log("DEBUG: spawning boat near coast " + str(_position));
			} else {
				// Spawn air anywhere that is flat
				waitUntil{!isNil "BIS_fnc_findSafePos"};
				_position = [MarkerPosition,0,DynamicVehicleArea,10,0,2000,0] call BIS_fnc_findSafePos;
				//diag_log("DEBUG: spawning air anywhere flat " + str(_position));
			};
		
		
		} else {
			// Spawn around buildings && 50% near roads
			if((random 1) > 0.5) then {
			
				waitUntil{!isNil "BIS_fnc_selectRandom"};
				_position = RoadList call BIS_fnc_selectRandom;
			
				_position = _position modelToWorld [0,0,0];
			
				waitUntil{!isNil "BIS_fnc_findSafePos"};
				_position = [_position,0,10,10,0,2000,0] call BIS_fnc_findSafePos;
			
				//diag_log("DEBUG: spawning near road " + str(_position));
			
			} else {
			
				waitUntil{!isNil "BIS_fnc_selectRandom"};
				_position = BuildingList call BIS_fnc_selectRandom;
			
				_position = _position modelToWorld [0,0,0];
			
				waitUntil{!isNil "BIS_fnc_findSafePos"};
				_position = [_position,0,40,5,0,2000,0] call BIS_fnc_findSafePos;
			
				//diag_log("DEBUG: spawning around buildings " + str(_position));
		
			};
		};
		// only proceed if two params otherwise BIS_fnc_findSafePos failed && may spawn in air
		if ((count _position) == 2) then { 
	
			_dir = round(random 180);
		
			_istoomany = _position nearObjects ["AllVehicles",50];
			if((count _istoomany) > 0) exitWith { diag_log("DEBUG: Too many vehicles at " + str(_position)); };
		
			//place vehicle 
			_veh = createVehicle [_vehicle, _position, [], 0, "CAN_COLLIDE"];
			_veh setdir _dir;
			_veh setpos _position;		
			
			if(DZEdebug) then {
				_marker = createMarker [str(_position) , _position];
				_marker setMarkerShape "ICON";
				_marker setMarkerType "DOT";
				_marker setMarkerText _vehicle;
			};	
		
			// Get position with ground
			_objPosition = getPosATL _veh;
		
			clearWeaponCargoGlobal  _veh;
			clearMagazineCargoGlobal  _veh;
			// _veh setVehicleAmmo DZE_vehicleAmmo;

			// Add 0-3 loots to vehicle using random cfgloots 
			_num = floor(random 4);
			_allCfgLoots = ["trash","civilian","food","generic","medical","military","policeman","hunter","worker","clothes","militaryclothes","specialclothes","trash"];
			
			for "_x" from 1 to _num do {
				_iClass = _allCfgLoots call BIS_fnc_selectRandom;

				_itemTypes = [];
				if (DZE_MissionLootTable) then{
					{
						_itemTypes set[count _itemTypes, _x select 0]
					} count getArray(missionConfigFile >> "cfgLoot" >> _iClass);
				}
				else {
					{
						_itemTypes set[count _itemTypes, _x select 0]
					} count getArray(configFile >> "cfgLoot" >> _iClass);
				};

				_index = dayz_CLBase find _iClass;
				_weights = dayz_CLChances select _index;
				_cntWeights = count _weights;
				
				_index = floor(random _cntWeights);
				_index = _weights select _index;
				_itemType = _itemTypes select _index;
				_veh addMagazineCargoGlobal [_itemType,1];
				//diag_log("DEBUG: spawed loot inside vehicle " + str(_itemType));
			};

			[_veh,[_dir,_objPosition],_vehicle,true,"0"] call server_publishVeh;
		};
	};
};

 

 

Any ideas? 

[syco]

You need more vehicles possible in your dynamic_vehicle.sqf. If MaxVehicleLimit = is higher then what is possible in dynamic_vehicle.sqf you will get that error. Added more vehicles to dynamic_vehicle.sqf or just increase the number next to each one or lower the MaxVehicleLimit = in your MPmission\init.sqf. The errors will go away. 

[MatthewK]

I hadn't even thought about that. Thanks Syco. 

Update:Spot on. No more errors and no duplicate vehicles. Cheers Syco :)