[Help] Detect players in bike.

[itsatrap]

Hello 

 

Hoping you can help we with my little error.

I was tried of all the bike's on my server, we use deploy bike and after a heavy PVP base fight there is always a butt load of bike laying around,

 

This is what I got now and it's almost works, the problem is that if a player is on his bike it gets deletede, but if he stands next to it, It will stay.

 

bike's a only meant to be deletede if no players is around 150m of them

 

its this line that finds all players, but it ignores players in vehicle's...

(isPlayer _x) && (alive _x) || (vehicle _x == _bike)

full script

private ["_pos","_delQtyBicycle","_qty","_allbicycle","_nearby","_bike"];
diag_log (format["CLEANUP: Finding unused bikes"]);
	_allBicycle = entities "Bicycle";
	_delQtyBicycle = 0;
	{
		if (_x getVariable "TempDeployed") then {
			_pos = getPosATL _x;
			_bike = _x;
				if ((count _pos > 0)) then {
					_nearby = {
						(isPlayer _x) && (alive _x) || (vehicle _x == _bike)
					} count (_pos nearEntities [["CAManBase"], 150]);
					
					if (_nearby==0) then {
						_x call dayz_perform_purge;
						sleep 0.05;
						_delQtyBicycle = _delQtyBicycle + 1;
					};
				};
			};
		sleep 0.001;
	} count _allbicycle;
	
	if (_delQtyBicycle > 0) then {
		_qty = count _allbicycle;
		diag_log (format["CLEANUP: Deleted %1 Bicycles out of %2",_delQtyBicycle,_qty]);
	};
diag_log (format["CLEANUP: Finding unused bikes Done"]);

Help me, Obi-Wan Kenobi. You're my only hope

 

 

 

[itsatrap]

no one :(

[Defent]

Like this?

_nearby = {isPlayer _x} && {alive _x} || {vehicle _x == _bike} count (_pos nearEntities [["CAMAnBase"], 150]);

[itsatrap]

 

Like this?

_nearby = {isPlayer _x} && {alive _x} || {vehicle _x == _bike} count (_pos nearEntities [["CAMAnBase"], 150]);

 

 

thats what I have now :/

[Defent]

thats what I have now :/

 

It's not the same as what you mentioned in your first post?

[itsatrap]

I must be blind can't see the difference :/

[Defent]

Changed ( with { etc. Have you tried it and how is it progressing? I'm intrested in this as well as I have loads of bikes on my server too.

[itsatrap]

private ["_pos","_delQtyBicycle","_qty","_allbicycle","_nearby","_bike"];
diag_log (format["CLEANUP: Finding unused bikes"]);
	_allBicycle = entities "Bicycle";
	_delQtyBicycle = 0;
	{
		if (_x getVariable "TempDeployed") then {
			_pos = getPosATL _x;
			_bike = _x;
				if ((count _pos > 0)) then {
					_nearby = {
						(isPlayer _x) && (alive _x)
					} count (_pos nearEntities [["CAManBase"], 250]);
					
					if ((_nearby==0) && ({alive _x} count crew _bike == 0)) then {
						_x call dayz_perform_purge;
						sleep 0.05;
						_delQtyBicycle = _delQtyBicycle + 1;
					};
				};
			};
		sleep 0.001;
	} count _allbicycle;
	
	if (_delQtyBicycle > 0) then {
		_qty = count _allbicycle;
		diag_log (format["CLEANUP: Deleted %1 Bicycles out of %2",_delQtyBicycle,_qty]);
	};
diag_log (format["CLEANUP: Finding unused bikes Done"]);

Working code :)

 

Fixed it with 

{alive _x} count crew _bike == 0

I run it from

server_cleanup.fsm

[Defent]

How exactly do you call it from the server_cleanup.fsm? That file has always confused me.

 

Also, did you add the variable TempDeployed to your deploy bike script?

[itsatrap]

How exactly do you call it from the server_cleanup.fsm? That file has always confused me.

 

Also, did you add the variable TempDeployed to your deploy bike script?

Read this about the fsm https://community.bistudio.com/wiki/FSM

I made it download my pbo and have a look I'm not near my pc