Displaying Object information in system chat

[piggd]

What I am trying to do is give a hot key so that you can pull the ObjectID, ObjectUID , Classname and ChracterID (admin only) from an object so I can trace it back to the DB at a latter date,  The key sends to the system chat fine but all I am getting is the labels no Variable data.  What am I doing wrong?

 

        if (_dikCode == 0x3E) then {
            _cursorTarget = cursorTarget;
            _isAdmin = (PDZE_dayz_playerUID in PDZE_AdminList);
            if(!isNil "_cursorTarget") then {
                _typeOfCursorTarget = typeOf _cursorTarget;
                _vehicle_ID = _cursorTarget getVariable ["ObjectID","0"];
                _vehicle_UID = _cursorTarget getVariable ["ObjectUID","0"];
                systemChat(format["Classname: ",_typeOfCursorTarget]);
                systemChat(format["Object ID: ", _vehicle_ID]);
                systemChat(format["Object UID: ",_vehicle_UID]);
                if (_isAdmin) then {
                    _ownerID = _cursorTarget getVariable ["CharacterID","0"];
                    systemChat(format["Owner UID: ", str(_ownerID)]);
                };
                hintSilent "";
                _handled = true;
            } else {
                hintSilent "";
                _handled = true;
            };
        };
 

[piggd]

Any thoughts?

[deadeye]

Each one of your strings in the format command has to have a %1 before the closing quote.
 

systemChat(format["Classname: %1",_typeOfCursorTarget]);

[piggd]

Ahh yes taht is it, thank you so much.