Bunker Event

[He-Man]

There are some (currently) unused bunkers in the Epoch files and I thought, what can we do with them...???
So I have written a small script to spawn them in a configureable square.

It is just a small "fun-event", that needs Admin support!
Only the doors between the bunkers are opened. So nobody can enter it from outside. (Only ported in Players can enter this event)
You can also configure some missing bunkers for a bit more opened feeling.

By default, loot is spawning. To disable it, you have to add this line (already in experimental):
https://github.com/EpochModTeam/Epoch/commit/e033973debd25bb8d16582a194bd62d2a731cb1a

Here are 2 small Videos from the "Event":
http://plays.tv/video/5b7b30a4cb1bc433b6/bunker2
https://plays.tv/video/5aa5961bd853eb1462/bunker-event
 

You have to run this Server Side by console or via "if (isserver) then {...};"
By default it is located in the salt lake on Altis, but you can change the parameters by yourself at the bottom of the script.

 

_BunkerEvent = {
	params ["_startpos","_countx","_county","_skip",["_loot",true]];
	_bunkerarr = ["bunker_epoch_01","bunker_epoch_02","bunker_epoch_03","bunker_epoch_04","bunker_epoch_06","bunker_epoch_09","bunker_epoch_10","bunker_epoch_11","bunker_epoch_12","bunker_epoch_13","bunker_epoch_14","bunker_epoch_15"];
	_spawnpos = [];
	{
		_spawnpos pushback _x
	} foreach _startpos;
	_dist = 12.9;
	for "_i" from 1 to _county do {
		for "_k" from 1 to _countx do {
			if !([_k,_i] in _skip) then {
				_veh = createVehicle [selectrandom _bunkerarr, _spawnpos, [], 0, "CAN_COLLIDE"];
				if (!_loot) then {
					_veh setvariable ['EPOCH_Skiploot',true,true];
				};
				_veh setposasl _spawnpos;
				_veh animate ["One",0];
				_veh animate ["Two",0];
				_veh animate ["Three",0];
				_veh animate ["Four",0];
				if (_i == 1) then {
					_veh animate ["Four",1];
				};
				if (_i == _county) then {
					_veh animate ["Three",1];
				};
				if (_k == 1) then {
					_veh animate ["Two",1];
				};
				if (_k == _countx) then {
					_veh animate ["One",1];
				};
			};
				_spawnpos set [0,(_startpos select 0) + _dist*_k];
		};
		_spawnpos set [0,(_startpos select 0)];
		_spawnpos set [1,(_startpos select 1)+_dist*_i];
	};
};

_startpos = [23807.1,18623.1,3.19];
_countx = 10;
_county = 10;
_skip = [[3,3],[8,3],[3,8],[8,8]];
_loot = false;
[_startpos,_countx,_county,_skip,_loot] call _BunkerEvent;

 

[DirtySanchez]

Love it! Thanks @He-Man